1. 594EIP_v6.EXE Driver
2. 594EIP.INF File Contents

594EIP.INF Driver File Contents (594EIP_v6.EXE)

;;
;; Installit script to build 594e w/ip routing system disk and/or setup disk
;;

DefineVariables
  Number [sysdisk] := 0
  Number [setdisk] := 0
  Number [success]  := 0
  Number [successsys]  := 0
  Number [successset]  := 0
  Number [RequiredSpace] := 1440000
  Text   [version]
  Text   [imgName]
  Text   [systemImgName]
  Text   [setupImgName]
  Text   [drive]
  Text   [disk]
EndDefineVariables

SetAllowEscape On
SetAllowExit Off

;;
;; START OF MAIN PROGRAM
;;
;;
;; Read the VERSION file
;;
ExamineTextFile 594eip.ver
[version] := Line 1
[systemImgName] := Line 2
[setupImgName] := Line 3

;;
;; Read the LANGUAGE text file
;; Then display the top and bottom lines and the welcome screen
;;
ExamineTextFile 594eip.lng

[String1] := Line 2
[String2] := Line 4

SetTopLineTo BlankString
SetTopLineTo [String1] [version]
SetBottomLineTo [String2]

:welcome
[String1] := Line 6
[String2] := Line 7
[String3] := Line 8
[String4] := Line 9
[String5] := Line 10
[String6] := Line 11
[String7] := Line 12
[String8] := Line 13
[String9] := Line 14
[String10] := Line 15
[String11] := Line 16

Dialog
  [String1] 
  [String2] 
  [String3]
  [String4]
  [String5] 
  [String6]
  [String7] 
  [String8]
  [String9] 
  [String10]
  [String11] 
EndDialog

If Escaped
   Do AreYouSure
   goto welcome
EndIf

;;
;; Select diskettes to build (594e IP, SETUP, BOTH)
;;
:selectdk
[String1] := Line 30
[String2] := Line 31
[String3] := Line 32
[String4] := Line 33

GetMenuChoice Highlight 1 UseHeader "[String1]"
  [String2]
  [String3]
  [String4]
EndGetMenuChoice

If Escaped
   Do AreYouSure
   goto selectdk
EndIf

InCase Choice is
  =1: [sysdisk] := 1
  =2: [setdisk] := 1
  =3: [sysdisk] := 1
      [setdisk] := 1
EndInCase

;;
;; Figure out what drive to use and verify that its 1.44M
;;
:getdrive

[String1] := Line 45
[String2] := Line 46
[String3] := Line 47

GetMenuChoice Highlight 1 UseHeader "[String1]"
  [String2]
  [String3]
EndGetMenuChoice

If Escaped
   Do AreYouSure
   goto getdrive
EndIf

InCase Choice is
  =1: [drive] := "A"
  =2: [drive] := "B"
EndInCase

If .not. DriveClassOf [drive] = FLOPPY144
   [String1] := Line 50
   popup [String1]
   goto getdrive
EndIf

;;
;; Build the 594e IP diskette
;;
[imgName] := [systemImgName]
[disk] := Line 25
If [sysdisk] = 1
   [success] := 0
   Do make_disk
   If [success] = 1
      [successsys] := 1
   EndIf
EndIf

;;
;; Build the SETUP diskette
;;
[imgName] := [setupImgName]
[disk] := Line 26
If [setdisk] = 1
   [success] := 0
   Do make_disk
   If [success] = 1
      [successset] := 1
   EndIf
EndIf

;;
;; Browse the README.TXT file if desired
;;
:breadme
[String1] := Line 40
[String2] := Line 41
[String3] := Line 42

GetMenuChoice Highlight 1 UseHeader "[String1]"
  [String2]
  [String3]
EndGetMenuChoice

If Escaped
   Do AreYouSure
   goto breadme
EndIf

InCase Choice is
  =1: BrowseFile readme.txt
EndInCase

;;
;; operation is done, so display results
;;

Do Results  

;; END OF MAIN PROGRAM
;;
;;
;;
;;
;; PROCEDURES USED:
;;
;;
;;
;; Procedure (1)
;; 
;; Procedure to Build a 594 disk
;;
Procedure make_disk

;;
;; request disk be inserted
;;
:retry
[String1] := Line 35
[String2] := Line 36
[String3] := Line 37
[String4] := "    "

Dialog
  [String1] [disk] Version [version]
  [String4]
  [String2]:
     [String4] [disk] Version [version]
  [String4]
  [String3] [drive]:
EndDialog

If Escaped
   Do AreYouSure
   goto retry
EndIf

;;
;; Check to make sure the disk is blank
;;
:do_it_again
While [RequiredSpace] > FreeSpaceOnDrive [drive]
:dspagain
   [String1] := Line 38
   [String2] := Line 51
   [String3] := Line 52
   [String4] := Line 53

   GetMenuChoice Highlight 1 UseHeader "[String1]"
        [String2]      ;; insert new diskette
        [String3]      ;; overwrite existing
        [String4]      ;; abort
   EndGetMenuChoice

   If Escaped
      Do AreYouSure
      goto dspagain
   EndIf

   InCase Choice is
     =1: goto do_it_again
     =2: goto fdup
     =3: goto skip_it
   EndInCase
EndWhile

;;
;; FDUP the .img file to the floppy
;;

:fdup

run FDUP [imgName] [drive]: SwapOut NoPrompt

;; if child process does execute, check return code,
;; else display
;;     Error occurred while trying to run
;;     the diskette duplication software FDUP.

If OSErrorCode = 0

;; if child process is aborted by user (pressing Esc key ret code = 34)
;; display are you sure message

   If OSExitCode = 34
      Do AreYouSure
      goto dspagain
   EndIf

;; if child process return code is no good, error, then display no success
   If OSExitCode <> 0
:nosuccess
      [String1] := Line 55
      [String2] := Line 56
      [String3] := Line 57

      GetMenuChoice Highlight 1 UseHeader "[String1]"
        [String2]
        [String3]
      EndGetMenuChoice

      If Escaped
         Do AreYouSure
         goto nosuccess
      EndIf

      InCase Choice is
        =1: goto retry
        =2: goto skip_it
      EndInCase

   else
      [success]  := 1
      goto skip_it
   EndIf
else
   [String1] := Line 85
   popup [String1]
   goto skip_it

EndIf


:skip_it
EndProcedure

;;
;;
;;
;;
;; Procedure (2)
;;
;;
;; Are You Sure
;;
Procedure AreYouSure

;;
;; Ask are you sure question!
;;
   [String1] := Line 65

   Dialog [YesOrNo1]
     [String1]
   EndDialog

   If [YesOrNo1] = YesCharacter
     Do Results
     SoLong
   EndIf

EndProcedure


;;
;;
;;
;; Procedure (3)
;;
;; Results
;;
;;
;;
Procedure Results

;;
;; Display results!
;;

if ([successsys] = 1) .AND. ([successset] = 1)
   [String1] := Line 72
   [String2] := "    "
   [String3] := Line 82
   [String4] := Line 83
else
   if ([successsys] = 1)
      [String1] := Line 73
      [String2] := "    "
      [String3] := Line 79
      [String4] := Line 80
   else
      if ([successset] = 1)
         [String1] := Line 74
         [String2] := "    "
         [String3] := Line 79
         [String4] := Line 80
      else
         [String1] := Line 75
         [String2] := "    "
         [String3] := "    "
         [String4] := "    "
      EndIf
   EndIf
EndIf

Dialog
  [String1] 
  [String2] 
  [String3]
  [String4]
EndDialog

EndProcedure