1. A370-0022-0100Ver330.exe Driver
2. AUTOEXEC.TXT File Contents

AUTOEXEC.TXT Driver File Contents (A370-0022-0100Ver330.exe)

@echo off
REM FIND RAM DRIVE and then set target drive to one higher
\findramd.exe
if errorlevel 3 set RAMD=c
if errorlevel 4 set RAMD=d
if errorlevel 5 set RAMD=e
if errorlevel 6 set RAMD=f
if errorlevel 7 set RAMD=g
if errorlevel 8 set RAMD=h
if errorlevel 9 set RAMD=i

a:\
path %RAMD%:\;\

if %config% == intrp_upd goto cd_done
a:\checkit.exe V
if errorlevel 11 goto ao_cd
if errorlevel 10 goto mit_cd
goto ao_cd

:ao_cd
device a:\cdrom\aoatapi.sys /D:IDECD001
goto cd_done

:mit_cd 
device a:\cdrom\mtmcdai.sys /D:IDECD001
goto cd_done

:cd_done
a:\DOS\MSCDEX /D:bpcddrv$ /L:Z > NUL
a:\DOS\MSCDEX /D:IDECD001 /L:Z > NUL
if not exist z:\utility\flashccl.exe goto errorcd

copy z:\utility\flashccl.exe %RAMD%:

echo.
echo Checking VGA BIOS type...

z:\utility\checkit.exe V
if errorlevel 11 goto notsupp
if errorlevel 10 goto foundvia
if errorlevel 9 goto foundemp
if errorlevel 8 goto found810
if errorlevel 7 goto foundopt
if errorlevel 6 goto founds3
if errorlevel 5 goto found550
if errorlevel 4 goto foundem
if errorlevel 3 goto founddm
if errorlevel 2 goto found69
if errorlevel 1 goto found65
if errorlevel 0 goto notsupp
goto error

:notsupp
echo This CD does not support the Video Chip Detected
goto end

:found65
echo 65555 Chips detected
set BIOSNAME=bios65.rom
copy z:\tx\plat_tx.bin  %RAMD%:\platform.bin
copy z:\tx\%BIOSNAME%   %RAMD%:\%BIOSNAME%
copy z:\tx\phlash.exe   %RAMD%:
goto romfound

:found69
echo 69000 Chips detected
set BIOSNAME=bios69.rom
copy z:\tx\plat_tx.bin  %RAMD%:\platform.bin
copy z:\tx\%BIOSNAME%   %RAMD%:\%BIOSNAME%
copy z:\tx\phlash.exe   %RAMD%:
goto romfound

:founddm
checkit.exe -A
if errorlevel 1 goto fnd_sum2
REM
REM Summa 1 board found
REM 
echo.
echo. IMPORTANT CAUTION: If the BIOS is being upgraded from version 2.1.0.9 or
echo.                    earlier, please note that the defaults for COM C & D
echo.                    are different.  See README.TXT file for more detail.
echo.
echo SMI 3DM Chip detected (7401)
set BIOSNAME=biosl_dm.rom
goto smicom

fnd_sum2:
REM
REM Summa 2 board found
REM 
echo SMI 3DM Chip with ESS1989 Audio detected
set BIOSNAME=acpi_xm.rom
goto smicom

:foundemp
echo SMI EM+ detected
set BIOSNAME=biosl_em.rom
goto sm_deter

:foundem
echo.
echo. IMPORTANT CAUTION: If the BIOS is being upgraded from version 2.1.0.9 or
echo.                    earlier, please note that the defaults for COM C & D
echo.                    are different.  See README.TXT file for more detail.
echo.
echo SMI 3EM Chip detected (7452/7453/7454/7455)
set BIOSNAME=biosl_em.rom

:sm_deter
rem Now try to determine board type
z:\utility\checkdmi 2 Summa
if errorlevel 1 goto smicom
echo 7454/7455 detected
set BIOSNAME=bios_old.rom

:smicom
copy z:\bx\plat_bx.bin  %RAMD%:\platform.bin
copy z:\bx\%BIOSNAME%   %RAMD%:\%BIOSNAME%
copy z:\bx\phlash.exe   %RAMD%:
goto romfound

:found550
echo C&T 65550 detected
goto notsupp

:founds3
echo S3 Trio 640 detected
goto notsupp

:foundopt
echo No VGA on OPTI motherboard detected
goto notsupp

:found810
echo Intel 810 detected
set BIOSNAME=bios_810.rom
copy z:\810\plat_810.bin %RAMD%:\platform.bin
copy z:\810\%BIOSNAME%   %RAMD%:\%BIOSNAME%
copy z:\810\phlash.exe   %RAMD%:\phlash.exe
goto romfound

:foundvia
echo VIA VGA detected
set BIOSNAME=bios_via.wph
copy z:\via\%BIOSNAME%          %RAMD%:\%BIOSNAME%
copy z:\phlash16\phlash16.exe   %RAMD%:
goto phlash16

:phlash16
%RAMD%:
if %config% == auto_upd goto doit16
echo.
echo Press Ctrl-C to abort or any other key to flash BIOS
pause
flashccl %BIOSNAME% /e /16
goto end

:doit16
echo.
flashccl %BIOSNAME% /16
goto end

:romfound
%RAMD%:
if %config% == auto_upd goto doitnow
echo.
echo Press Ctrl-C to abort or any other key to flash BIOS
pause
flashccl %BIOSNAME% /e
goto end

:doitnow
echo.
flashccl %BIOSNAME%
goto end

:errorcd
echo.
echo A problem has occured with the CD-ROM drive
goto end

:error
echo.
echo Error occurred
goto end

:end